Mac OSX 10.5.8: Gefakte DHL-Mail mit Link geöffnet
 

Hallo an alle,

ich Depperl habe vor drei Tagen eine der getürkten DHL-Mails geöffnet und auch auf den Link geklickt. Habe ich mir jetzt den Trojaner geholt? Ich merke erstmal noch nichts davon.

Meine Recherche beim BSI ergab, dass es sich wohl um den Trojaner Geodo handelt. Auf meine Anfrage bei der Servicehotline erhielt ich die Auskunft, er könne überall aktiv werden (also auch auf Mac). Ich solle eine Antivirensoftware drüberlaufen lassen und den Virus in Quarantäne setzen.

Uff, bin nicht gerade sehr versiert in Computerdingen. Habe mir das Antivirenprogramm ClamXav heruntergeladen und über meinen Rechner laufen lassen. Es hat nichts gefunden. Heißt das, der Mac ist nicht befallen?

Meine Fragen im Einzelnen:

- Kann es sein, dass der Virus trotz AV-Software noch irgendwo lauert? Kann ich ihn per Mail, Stick oder Datei auf einen anderen Computer, insbesondere einen PC, übertragen?

- Kann ich den Mac noch fürs Online-Banking nutzen? (Hatte anschließend mein Konto sperren und meine Benutzerdaten ändern lassen.)

- Ist ClamXav als Antivirensoftware okay?

- Gibt es für meinen zweiten älteren Mac (Betriebssystem OSX 10.4.11) überhaupt ein AV-Programm?

Hoffentlich sind das nicht zu viele Fragen! Hoffe auf euer Feedback und bin dankbar für alle Tipps und Hinweise!!!

ich schieb dich mal ins passende Forum :)

Hallo diev :hallo:

1. Versteckte Dateien/Ordner sichtbar machen

1. Öffne bitte dein Terminal. Spotlight -> Terminal eingeben und starten.
2. Gebe folgenden Befehl in das Terminal ein:
   
   Code:

   ---

   defaults write com.apple.finder AppleShowAllFiles TRUE;killall Finder

   ---

3. Um es rückgängig zu machen ersetze den Wert TRUE durch FALSE.

2. Log erstellen mit AdwareMedic
Hinweis: AdwareMedic läuft erst ab Mac OS X 10.7 (Lion) oder höher.

1. Lade dir bitte AdwareMedic herunter
2. Starte das dmg-Archiv und installier es.
3. Starte AdwareMedic und öffne das Menü Scanner. Dort den Punkt Take System Snapshot
4. Kopiere das Ergebnis des Logs in das Clipboard und füge es hier in Code-Tags ein.

3. Alternative Log erstellen mit EtreCheck (oder beides :lach:)

1. Lade bitte EtreCheck herunter.
2. Archiv entpacken und die App auf den Desktop oder in den Programm-Ordner legen.
3. Starten und anschließend das Ergebnis ins Clipboard kopieren.
4. Füge es hier in Code-Tags ein.

Hallo Dante12,
danke erstmal für die Infos! Ich kapier nur nicht, wie ich das mit Terminal mache. Wenn ich das Programm öffne, erscheint nur ein Fenster mit
Last login: Fri Sep 24 14:56:01 on console (etc)
Wie soll ich da etwas eingeben? Und wo finde ich den Code??

Das ist OK so. Wenn du das Terminal öffnest zeigt es dir die letzte Verwendung.

Diesen Inhalt oben bitte in dein Terminal kopieren (Klicke auf Alles auswählen und anschließend mit Command-C kopieren), mit Command-V in dein Terminal einfügen und mit Enter bestätigen. Dieser Befehl sorgt dafür, dass im Finder alle versteckten Dateien und Ordner angezeigt werden.

Befolge danach die Anweisungen in den Punkten 2 und 3.

Sorry, eine schwere Geburt, aber vielen Dank, jetzt hab ichs kapiert und gemacht. Nun sagt er mir aber, dass ich die runtergeladene EtreCheck-Version nicht mit meiner OSX Version verwenden kann (10.5.8). Gibts noch eine Alternative dazu?

Hallo diev,

Ich hab jetzt auf die schnelle ein Script erstellt das du mit dem Script Editor ausführen kannst. Ich kann nicht garantieren ob es läuft. Getestet habe ich es ab Mac OS X 10.9.

1. TextWranger installieren falls nicht vorhanden
Der Standardtexteditor TextEdit hat da seine Probleme mit großen Datenmengen. Deshalb nutze ich für die Ausgabe TextWrangler. Wenn du es noch nicht auf dein System hast kannst du es dir vom AppStore runterladen - es ist kostenlos.

2. Anleitung für die Verwendung des Scripts.

1. Installiere bitte TextWrangler wie oben beschrieben und starte das Programm.
2. Kopiere den nachfolgenden Inhalt aus der Code-Box. Dazu klicke auf Alles auswählen und kopiere es mit Command-C.
   
   
   Code:

   ---

   (*
--------------------------------------------------------------------
 System Reporter
 Testversion
*)

global kHomeFolderPath
set kHomeFolderPath to POSIX path of (path to home folder)

global gOutput
set gOutput to "System Report Log" & return & "Scanned " & (current date)
set osver to system version of (system info) -- Get system version
set gOutput to gOutput & return & "Mac OS X version " & osver



-- Get login items
tell application "System Events"
        set loginItems to the name of every login item
end tell
if length of loginItems is 0 then
        set loginItemsOutput to "None"
else
        set firstItem to true
        repeat with oneItem in loginItems
                if firstItem then
                        set loginItemsOutput to oneItem
                        set firstItem to false
                else
                        set loginItemsOutput to loginItemsOutput & return & oneItem
                end if
        end repeat
end if
AddToOutput(loginItemsOutput, "Login items")

-- Get sandboxed login items
set theOverrides to GetOutputForShellScript("plutil -p /private/var/db/launchd.db/com.apple.launchd.peruser.501/overrides.plist", "No login items")
AddToOutput(theOverrides, "Sandboxed login items (overrides.plist)")

-- Get contents of specific interesting folders
set thingsToScan to {{"Startup items", "/Library/StartupItems"}, ¬
        {"System startup items", "/System/Library/StartupItems"}, ¬
        {"User launch agents", "~/Library/LaunchAgents"}, ¬
        {"Root launch agents", "/Library/LaunchAgents"}, ¬
        {"Root launch daemons", "/Library/LaunchDaemons"}, ¬
        {"Safari extensions", "~/Library/Safari/Extensions/"}, ¬
        {"Applications", "Applications"}, ¬
        {"Preference Panes", "Library/PreferencePanes"}, ¬
        {"User Internet Plug-Ins", "~/Library/Internet\\ Plug-Ins"}, ¬
        {"Internet Plug-Ins", "/Library/Internet\\ Plug-Ins"}}
repeat with oneThing in thingsToScan
        set nameOfThing to item 1 of oneThing
        set pathToThing to item 2 of oneThing
        try
                set contentsOfThing to (do shell script ("ls -Al " & pathToThing))
        on error errMsg number errn
                if errn = 1 then
                        set contentsOfThing to "Folder does not exist."
                else
                        set contentsOfThing to "Error " & errn & " : " & errMsg
                end if
        end try
        if contentsOfThing is "" then
                set contentsOfThing to "None"
        end if
        AddToOutput(contentsOfThing, nameOfThing)
end repeat

-- Get Chrome extensions
set chromeExtensions to GetChromeExtensionInfo()
AddToOutput(chromeExtensions, "Chrome extensions")
set chromeExternalExtensions to GetChromeExternalExtensionInfo()
AddToOutput(chromeExternalExtensions, "Chrome external extensions")

-- Get Firefox extensions
set mozillaExtensions to GetFirefoxExtensionInfo(kHomeFolderPath & "Library/Application Support/Mozilla/Extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/")
AddToOutput(mozillaExtensions, "Mozilla extensions")
set firefoxProfileFolder to GetFirefoxDefaultProfileFolder()
if firefoxProfileFolder is not "" then
        set firefoxExtensions to GetFirefoxExtensionInfo(firefoxProfileFolder & "extensions/")
else
        set firefoxExtensions to "Folder does not exist"
end if
AddToOutput(firefoxExtensions, "Firefox extensions")

-- Get third-party kexts
set kextOutput to (do shell script "kextstat -l | grep -v com.apple | cut -c53-")
if length of kextOutput is 0 then
        set kextOutput to "None"
end if
AddToOutput(kextOutput, "Third-party kexts")

-- Get user and root cron tasks
try
        set userCronOutput to (do shell script "crontab -l")
on error
        set userCronOutput to "No user cron tasks"
end try
try
        set rootCronOutput to (do shell script "crontab -l" with administrator privileges)
on error
        set rootCronOutput to "No root cron tasks"
end try
set cronOutput to "User tasks:" & return & userCronOutput & return & "Root tasks:" & return & rootCronOutput
AddToOutput(cronOutput, "Cron tasks")

-- Get LoginHook
set theLoginHook to GetOutputForShellScript("defaults read com.apple.loginwindow LoginHook", "No login hooks")
AddToOutput(theLoginHook, "LoginHook")

-- Apps to relaunch at restart
try
        set theFolder to POSIX path of (path to home folder) & "/Library/Preferences/ByHost/"
        tell application "Finder"
                set theItems to name of items of folder (theFolder as POSIX file)
        end tell
        set foundItem to ""
        repeat with oneItem in theItems
                if oneItem begins with "com.apple.loginwindow" then
                        set foundItem to theFolder & oneItem
                        exit repeat
                end if
        end repeat
        if foundItem = "" then
                set plistContents to "Property list not found"
        else
                set plistContents to (do shell script "plutil -p " & foundItem)
        end if
on error errMsg number errn
        set plistContents to "Error: " & errMsg & " : " & errn
end try
AddToOutput(plistContents, "Apps to relaunch at restart")

-- Get launchd.conf
set theStartupItems to GetOutputForShellScript("cat /etc/launchd.conf", "No custom settings")
AddToOutput(theStartupItems, "Launchd configuration")

-- Get DNS settings
try
        set theDNS to (do shell script "nslookup thesafemac.com | grep Server.*")
on error
        set theDNS to "Error getting DNS settings"
end try
AddToOutput(theDNS, "DNS settings")

-- Get hosts file
try
        set theHosts to (do shell script "cat /etc/hosts")
on error
        set theHosts to "Error getting hosts file contents"
end try
AddToOutput(theHosts, "Hosts file")

-- Done creating output, now what do we do with it?
set dialogResult to display alert "Send or view report?" as informational message "Do you want to send this information via e-mail using the Mail app, or open it in TextWrangler?" buttons {"Send with Mail", "Open in TextWrangler"}
if button returned of dialogResult is "Send with Mail" then
        tell application "Mail"
                set theNewMessage to make new outgoing message with properties {subject:"My system report", content:gOutput, visible:true}
                tell theNewMessage
                        make new to recipient at end of to recipients with properties {address:"forum-dante@posteo.eu"}
                end tell
        end tell
else
        set textEditName to "TextWrangler"
        tell application textEditName
                activate
                make new document
                set text of document 1 to gOutput
        end tell
end if


on AddToOutput(outputString, titleString)
        set formattedOutput to return & return & titleString & return & "---------------" & return & outputString
        set gOutput to gOutput & formattedOutput
end AddToOutput

on GetOutputForShellScript(theScript, err1Message)
        try
                set scriptOutput to (do shell script theScript)
        on error errMsg number errn
                if errn = 1 then
                        set scriptOutput to err1Message
                else
                        set scriptOutput to "Error " & errn & " : " & errMsg
                end if
        end try
        if scriptOutput = "" then
                set scriptOutput to err1Message
        end if
        return scriptOutput
end GetOutputForShellScript

-----------------------------------------------------------------------
-- Gets a path to the folder for the default profile in Firefox
-----------------------------------------------------------------------
on GetFirefoxDefaultProfileFolder()
        set firefoxProfileFolder to POSIX path of (path to home folder) & "Library/Application Support/Firefox/Profiles/"
        tell application "System Events" to set itemExists to exists disk item firefoxProfileFolder
        if not itemExists then
                return ""
        end if
       
        tell application "Finder"
                set allProfiles to name of folders of folder (firefoxProfileFolder as POSIX file)
        end tell
       
        repeat with oneFolder in allProfiles
                if oneFolder ends with ".default" then
                        return firefoxProfileFolder & oneFolder & "/"
                end if
        end repeat
       
        return ""
end GetFirefoxDefaultProfileFolder

-----------------------------------------------------------------------
-- Gets information about installed Chrome extensions
-----------------------------------------------------------------------
on GetChromeExtensionInfo()
        return GetInfoForFolderStyleChromeExtension(POSIX path of (path to home folder) & "Library/Application Support/Google/Chrome/Default/Extensions/")
end GetChromeExtensionInfo

-----------------------------------------------------------------------
-- Given a folder, iterates over the folders it contains looking for the "name"
-- field from any json files inside that folder. Returns a formatted list of
-- file names and grep search results.
-----------------------------------------------------------------------
on GetInfoForFolderStyleChromeExtension(inFolder)
        -- ignore default Chrome extensions
        set ignoreList to {"aohghmighlieiainnegkcijnfilokake", "apdfllckaahabafndbhieahigkjlhalf", "bepbmhgboaologfdajaanbcjmnhjmhfn", "blpcfgokakmgnkcojhhkbfbldkacnbeo", "coobgpohoikkiipiblmjeljniedjpjpf", "nmmhkkegccagdldgiimedpiccmgmieda", "pjkljhegncpnkpknbcohdijeoejaedia"}
       
        tell application "System Events" to set itemExists to exists disk item inFolder
        if not itemExists then
                return "Folder does not exist"
        end if
       
        tell application "Finder"
                set allExtensions to name of folders of folder (inFolder as POSIX file)
        end tell
        if (count of allExtensions) is 0 then
                return "None"
        end if
       
        set theOutput to ""
        repeat with oneExtension in allExtensions
                if oneExtension is not in ignoreList then
                        if theOutput is not "" then
                                set theOutput to theOutput & return
                        end if
                        tell application "System Events" to set theModDate to the modification date of item (inFolder & oneExtension)
                        set theOutput to theOutput & oneExtension & " : modified " & theModDate & return & "        -> "
                        try
                                set nameInfo to do shell script ("grep -r '\"name\":[        ]*\"[^\"]*\"' " & quoted form of inFolder & oneExtension & "/")
                        on error
                                set nameInfo to "Error getting extension information"
                        end try
                        set theOutput to theOutput & nameInfo
                end if
        end repeat
       
        if theOutput is "" then
                return "None"
        end if
       
        return theOutput
end GetInfoForFolderStyleChromeExtension

----------------------------------------------------------------------
-- Gets information about installed Chrome external extensions
-----------------------------------------------------------------------
on GetChromeExternalExtensionInfo()
        set userExtensionsInfo to GetInfoForFileStyleChromeExtension(POSIX path of (path to home folder) & "/Library/Application Support/Google/Chrome/External Extensions/")
        set globalExtensionsInfo to GetInfoForFileStyleChromeExtension("/Library/Application Support/Google/Chrome/External Extensions/")
       
        set theOutput to "  +++ For user +++" & return & userExtensionsInfo & return & "  +++ Global +++" & return & globalExtensionsInfo
       
        return theOutput
end GetChromeExternalExtensionInfo

-----------------------------------------------------------------------
-- Given a folder, iterates over the files it contains looking for the "name"
-- field from any json files inside that folder. Returns a formatted list of
-- file names and contents.
-----------------------------------------------------------------------
on GetInfoForFileStyleChromeExtension(inFolder)
        tell application "System Events" to set itemExists to exists disk item inFolder
        if not itemExists then
                return "Folder does not exist"
        end if
       
        tell application "Finder"
                set allExtensions to name of files of folder (inFolder as POSIX file)
        end tell
        if (count of allExtensions) is 0 then
                return "None"
        end if
       
        set theOutput to ""
        repeat with oneExtension in allExtensions
                if theOutput is not "" then
                        set theOutput to theOutput & return
                end if
                try
                        set fileContents to do shell script ("cat " & quoted form of (inFolder & oneExtension))
                        set theOutput to theOutput & "--- Contents of " & oneExtension & " ---" & return & fileContents & return & "--- End Contents ---"
                on error
                        set theOutput to return & "Error getting extension information"
                end try
        end repeat
       
        if theOutput is "" then
                return "None"
        end if
       
        return theOutput
end GetInfoForFileStyleChromeExtension

-----------------------------------------------------------------------
-- Given a Firefox extension folder, outputs a list of the items in the folder,
-- as well as the name found in any install.rdf or manifest.xml files inside.
-- Searching will be done with egrep or zipgrep, and is not limited to those files,
-- though patterns will be used that should only be found in them.
-----------------------------------------------------------------------
on GetFirefoxExtensionInfo(inFolder)
        tell application "System Events" to set itemExists to exists disk item inFolder
        if not itemExists then
                return "Folder does not exist"
        end if
       
        tell application "Finder"
                set allExtensions to name of items of folder (inFolder as POSIX file)
        end tell
        if (count of allExtensions) is 0 then
                return "None"
        end if
       
        set theOutput to ""
        repeat with oneExtension in allExtensions
                if theOutput is not "" then
                        set theOutput to theOutput & return
                end if
                tell application "System Events" to set theModDate to the modification date of item (inFolder & oneExtension)
                set theOutput to theOutput & oneExtension & " : modified " & theModDate & return & "        -> "
               
                tell application "System Events" to set extensionKind to class of item (inFolder & oneExtension) as string
                if extensionKind is "folder" then
                        try
                                set nameInfo to do shell script ("egrep -r '(em:name=\"[^\"]*\")|(<ShortName>[^<]*</ShortName>)|(<em:name>[^<]*</em:name>)' " & quoted form of inFolder & oneExtension & "/")
                        on error
                                set nameInfo to "Error getting extension information"
                        end try
                else -- if the extension is a file
                        if oneExtension ends with ".xpi" then
                                try
                                        set nameInfo to do shell script ("zipgrep '<em:name>[^<]*</em:name>' " & quoted form of inFolder & oneExtension)
                                on error
                                        set nameInfo to "Error getting extension information"
                                end try
                        else
                                set nameInfo to "Unknown extension file format"
                        end if
                end if
                set theOutput to theOutput & nameInfo
        end repeat
       
        if theOutput is "" then
                return "None"
        end if
       
        return theOutput
end GetFirefoxExtensionInfo

   ---

3. Füge das Script mit Command-V in TextWrangler ein.
4. Speicher es unter den Namen Systemreport.scpt auf dein Desktop. TextWrangler kannst du danach beenden.
5. Führe bitte nun einen Doppelklick auf die Datei Systemreport.scpt die sich auf dein Desktop befindet. Daraufhin sollte sich der Script Editor mit dem Inhalt öffnen.
6. Klicke nun oben auf das Dreieck (steht für Ausführen) oder wähle aus dem Menü Script den Befehl Ausführen.
7. Wenn gefordert gebe dein Passwort ein.
8. Sollte jetzt alles ohne Probleme laufen, öffnet sich anschließend ein Dialogfenster. Klicke auf den Button Open in TextWrangler.

3. Bearbeitung und Posten

1. Gehe in TextWrangler auf das Menu Search und wähle dort Find.. aus.
2. Du siehst nun eine neue Eingabebox. Oben steht Find und darunter Replace.
3. Suche nach persönlichen Informationen wie z.B deinen Namen oder email-Adressen und mache sie unkenntlich indem du im Eingabefeld Find den gesuchten Text eingibst und im Eingabefeld Replace etwas anderes hineinschreibst z.B. xxxxx.
4. Klicke dann auf Replace All. Mit Command-Z kannst du Änderungen rückgängig machen.
5. Ist alles erledigt, kopiere nun den Inhalt mit Command-A und Command-C und füge es anschließend hier in deinem nächsten Post in Code-Tags ein.

Solltest du damit Probleme haben, dann versuche ich noch etwas anderes. Bitte schreib mir gleich ob du seit deinem Vorfall, Änderungen am System wahrgenommen hast. Zum Beispiel Pop-ups oder ähnliches.

Hallo Dante12,
ich dank dir vielmals, dass du dir die Mühe gemacht hast!! Das sieht nach echt viel Arbeit aus! Ich versuche es jetzt mal.
Noch eine kleine Frage zu Terminal: Soll ich da den gestrigen Vorgang wiederholen, d.h. den Code wieder reinkopieren? Und soll ich dabei den Inhalt (Last login etc) überschreiben oder den Code einfach nur dazukopieren?
Veränderungen oder Eigentümlichkeiten sind mir bisher noch nicht aufgefallen, habe mich aber kaum im Netz bewegt...
(...)
War inzwischen im App Store:
Leider scheint auch der TextWrangler nix für meinen alten Mac zu sein. Der App Store sagt: Zum Laden von TextWrangler benötigen Sie einen Mac mit OS X 10.6.6 oder neuer. :killpc:
Vielleicht gibts irgendwo die Möglichkeit, eine ältere Version von Etrecheck zu bekommen, etwa die 1.9.11? Hab leider keine "seriöse" Seite dazu gefunden.

Nein, wenn du es gestern ausgeführt hast, brauchst du es nicht noch mal machen. Die Einstellung geht nicht verloren.

Last Login ist Teil der Terminals und da brauchst du nix machen kommt immer wieder automatisch wenn du dein Terminal öffnest. Aufgrund des alters deines Betriebssystems vergiss das oben genannte Script. Das läuft dann auch nicht.

Wir machen das so wie du es gestern mit dem Terminal gemacht hast.

Hinweis: Das nachfolgende ist ein sehr langes Bash-Script das ausschließlich Daten sammelt und daraus ein Log erstellt.

1. Unten sieht du die Code-Box. Klicke auf Alles Auswählen und kopiere es mit Command-C.
2. Öffne dein Terminal und füge es dort ein mit Command-V.
3. Wenn eine Fehlermeldung kommt gebe im Terminal folgenden Befehl ein: exec bash und füge das Script noch einmal ein.

So sieht es aus wenn es ausgeführt wird...
http://www.trojaner-board.de/picture...&pictureid=554
4. Der Prozess dauert einige Zeit. Es werden 8 Prozesse ausgeführt und danach beendet sich das Script von alleine.
5. Du erhälst keine Rückmeldung wenn es beendet ist. Das erstellte Log befindet sich aber danach in der Zwischenablage (Clipboard).
6. Füge den Inhalt mit Command-V hier in deinem nächsten Post (bitte in Code-Tags! siehe Bild unten.)

Code-Tags:

Klicke auf das angezeigt Symbol und füge den Text wie im Bild angegeben.
http://www.trojaner-board.de/picture...&pictureid=555

Ist das als Fehlermeldung zu werten? Das sagt mein Terminal:
cp: /Library/Preferences/SystemConfiguration/preferences.plist.old: Permission denied
Password:

exec bash kann ich da leider nicht eingeben, er nimmt nix, er scheint auf ein Password zu warten.
Und woher weiß ich nachher, wann das Script beendet ist, wenn das gar nicht angezeigt wird??

Inzwischen habe ich das Script gelöscht, exec bash eingegeben und das Script nochmal reinkopiert. Es erscheint die gleiche Meldung wie oben ...

Über dem Eingabefenster steht übrigens Folgendes:
Terminal - sudo - 80x24

http://www.trojaner-board.de/picture...&pictureid=556

Sieh dir mal das Bild oben an.

- Oben in der Leiste steht der Name der Shell. Bei mir ist es die ZSH. Deshalb muss ich bei mir den Befehl exec bash vorher eingeben bevor ich das Script einfüge.

- Der Prompt (in Gelb) ist immer da! (sieht z.B. so aus: -% oder -$ oder was andereres. Davor steht der Name deines Rechners. Bei mir ist es abgedeckt deshalb siehst du es nicht.

Wenn ein Prozess ohne Rückmeldung beendet wird erscheint wieder der Prompt und wartet auf neue Befehle.

- In Grün ist der auszuführende Befehl in diesem Fall exec bash. Wenn du das eingeben hast und Enter/Return drückst, dann siehst du oben in der Leiste den Namen des Befehls.

Jetzt schau die bitte die Code-Box an:
Lese dir jeden Punkt zuerst komplett durch bevor du etwas machst.

1. Klicke oben auf den Button Alles Auswählen
2. Kopiere es mit Command-C. Jetzt befindet sich der Inhalt der Box in der Zwischenablage!
3. Mache jetzt nichts anderes! Und schaue dir das Bild unten an

http://www.trojaner-board.de/picture...&pictureid=554
So sieht es aus wenn das Script läuft. Befolge jetzt Schritt für Schritt die weiteren Anweisungen

4. Öffne dein Terminal
5. Gebe jetzt exec bash und dann Enter ein!
6. Füge jetzt den Inhalt der Zwischenablage mit der Tastenkombination Command-V in das Terminal.
7. Jetzt wird das Fenster geleert und danach steht dort Passwort:
8. Gebe jetzt das Passwort ein und drücke Enter. Das ist das mit dem du dich nach dem start des Rechners einloggst. Das Passwort selbst sieht du im Terminal nicht!
9. Danach wird das Script mit der Ausgabe [Process startet] gestartet. Es folgen insgesamt 8 Abläufe.
10. Wenn das Script fertig ist beendet sich das Terminal von alleine!
11. Schaue dir jetzt ein weiteres Bild an... :D
http://www.trojaner-board.de/picture...&pictureid=555

12. Klicke auf das Code-Box Symbol und füge jetzt den Inhalt mit Command-V dazwischen wie es im Bild angezeigt wird und Poste es bitte.

Wenn es dennoch weitere Probleme gibt bitte sofort melden. Ich wage noch einen letzten Schritt bevor mir die Optionen ausgehen.

Dank dir nochmal für deine Mühe! Leider seh ich keine Bilder, auch nicht in deinen bisherigen Posts. Muss ich da irgendeine Einstellung ändern?

(P.S. Die Sache mit den Code-Tags hab ich mir in euren Anleitungen schon angesehen, da weiß ich, was ich machen muss.)

Wie wäre es denn, wenn ich mir ein Update auf 10.6 besorge? Dann könnte man ja ganz normal mit EtreCheck arbeiten. Wäre das ratsam, upzudaten, trotz möglichem Virus?

Schreib mir bitte ob jetzt die Bilder sind.

Wegen eines fehlenden Logs würde ich nicht extra ein Upgrade machen. Aber ratsam ist es auf jeden Fall. Eine Neu-Installation würde ich aber vorziehen, da in den neueren Versionen viele Änderungen vorgenommen wurden. Da ist die Übernahme alter Einstellungen oft schwierig. Beste weg also Backup deiner persönlichen Daten und das Neu-Installieren auf eine jüngere Version.

Hallo Dante12,

jetzt sind die Bilder da!

Ich hab aber doch Bedenken, weiter in meinem Terminal herumzuwerkeln, sorry! Fühle mich zu sehr als Laie und fürchte, dass ich möglicherweise doch etwas nicht ganz richtig verstehe und mir dann erst recht Ärger mit meinem Rechner einhandle.

Deshalb hab ich mich nun doch zur letztdiskutierten Variante entschlossen, d.h. ich werde meinen Rechner so weit als möglich aufrüsten lassen. Der Virenscan kann dann miterfolgen, wenn der neue Arbeitsspeicher eingebaut wird.

Sorry, dass ich dich so viel Arbeit gekostet habe! Und danke dir noch mal ganz herzlich für deine Mühe! Ich habe jede Menge dabei gelernt! Und weiß jetzt auch, dass ich meinem guten alten Mac insgesamt ein bisschen mehr Aufmerksamkeit widmen sollte und nicht erst dann, wenn das Kind in den Brunnen gefallen ist ... ;-)

Hoffe, das ist okay.

Kein Problem dafür bin ich da um so gut es geht zu helfen. :daumenhoc: